From 921a6f40fb74312a35d45a9b5f8b7d3e8dcd69f9 Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Thu, 18 Apr 2024 22:44:45 -0400
Subject: [PATCH 1/6] Add Fossil VCS support

Commit amended on 2024-04-19 to update the README.
---
 README.md                          |  8 ++++
 functions/__bobthefish_glyphs.fish |  4 ++
 functions/fish_prompt.fish         | 67 ++++++++++++++++++++++++++++++
 3 files changed, 79 insertions(+)

diff --git a/README.md b/README.md
index 3163f1a..9dbc3c1 100644
--- a/README.md
+++ b/README.md
@@ -63,6 +63,10 @@ This theme is based loosely on [agnoster][btf-agnoster].
      * Unpushed commits (**`+`**)
      * Unpulled _and_ unpushed commits (**`±`**)
      * _Note that not all of these have been implemented for hg yet :)_
+ * Fossil status:
+     * Dirty working directory (**`*`**)
+     * Untracked files (**`…`**)
+     * Conflicts (**`!`**)
  * Abbreviated project-relative path
 
 
@@ -244,6 +248,10 @@ If you do any Git worktree shenanigans, setting this to `yes` will fix incorrect
 
 This feature is disabled by default. Use `yes` to enable Mercurial support in Bobthefish. If you don't use Mercurial, leave it disabled because it's ... not fast.
 
+#### `set -g theme_display_fossil yes`
+
+This feature is also disabled by default. It should be faster than Mercurial, but if you aren't using Fossil it's safe to leave disabled.
+
 #### `set -g theme_vcs_ignore_paths /some/path /some/other/path{foo,bar}`
 
 Ignore project paths for Git or Mercurial. Supports glob patterns.
diff --git a/functions/__bobthefish_glyphs.fish b/functions/__bobthefish_glyphs.fish
index c0f13e2..036a66c 100644
--- a/functions/__bobthefish_glyphs.fish
+++ b/functions/__bobthefish_glyphs.fish
@@ -49,6 +49,9 @@ function __bobthefish_glyphs -S -d 'Define glyphs used by bobthefish'
   set -x git_minus_glyph      '-'
   set -x git_plus_minus_glyph '±'
 
+  # Fossil glyph (it reuses most of the git glyphs)
+  set -x fossil_glyph '🦴'
+
   # Disable Powerline fonts (unless we're using nerd fonts instead)
   if [ "$theme_powerline_fonts" = "no" -a "$theme_nerd_fonts" != "yes" ]
     set private_glyph           \u29B8 ' '
@@ -83,6 +86,7 @@ function __bobthefish_glyphs -S -d 'Define glyphs used by bobthefish'
     set git_stashed_glyph    \uF0C6 '' # nf-fa-paperclip
     set git_untracked_glyph  \uF128 '' # nf-fa-question
     # set git_untracked_glyph  \uF141 '' # nf-fa-ellipsis_h
+    set fossil_glyph '󰂹'
 
     set git_ahead_glyph      \uF47B # nf-oct-chevron_up
     set git_behind_glyph     \uF47C # nf-oct-chevron_down
diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index 7e5f3ba..fedd779 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -72,6 +72,11 @@ function __bobthefish_git_branch -S -d 'Get the current git branch (or commitish
     end
 end
 
+function __bobthefish_fossil_branch -S -d 'Get the current fossil branch'
+    set -l branch (command fossil branch 2>/dev/null)
+    echo "$branch_glyph $branch"
+end
+
 function __bobthefish_hg_branch -S -d 'Get the current hg branch'
     set -l branch (command hg branch 2>/dev/null)
     set -l book (command hg book | command grep \* | cut -d\  -f3)
@@ -190,6 +195,17 @@ function __bobthefish_git_project_dir -S -a real_pwd -d 'Print the current git p
     end
 end
 
+function __bobthefish_fossil_project_dir -S -a real_pwd -d 'Print the current fossil project base directory'
+    [ "$theme_display_fossil" = 'yes' ]
+    or return
+
+    set -q theme_vcs_ignore_paths
+    and [ (__bobthefish_ignore_vcs_dir $real_pwd) ]
+    and return
+
+    command fossil info 2>/dev/null | sed '3q;d' | string split ' ' -f2 -n | string trim --right --chars=/
+end
+
 function __bobthefish_hg_project_dir -S -a real_pwd -d 'Print the current hg project base directory'
     [ "$theme_display_hg" = 'yes' ]
     or return
@@ -1020,6 +1036,54 @@ end
 # VCS segments
 # ==============================
 
+function __bobthefish_prompt_fossil -S -a fossil_root_dir -a real_pwd -d 'Display the actual fossil state'
+    set fossil_statuses (command fossil changes --differ 2>/dev/null | cut -d' ' -f1 | sort -u)
+
+    # Fossil doesn't really stage changes; untracked files are ignored, tracked files are committed by default
+    # It also syncs by default when you commit, and monitors for conflicts (which will be reported here)
+    for line in $fossil_statuses
+        switch $line
+            case ADDED UPDATED EDITED DELETED RENAMED
+                # These can really just all be dirty, then
+                set dirty $git_dirty_glyph
+            case EXTRA
+                set new $git_untracked_glyph
+            case CONFLICT
+                set conflict '!'
+        end
+    end
+
+    set flags "$dirty$new$conflict"
+
+    [ "$flags" ]
+    and set flags " $flags"
+
+    set -l flag_colors $color_repo
+    if [ "$dirty" ]
+        set flag_colors $color_repo_dirty
+    end
+
+    __bobthefish_path_segment $fossil_root_dir project
+
+    __bobthefish_start_segment $flag_colors
+    echo -ns $fossil_glyph ' '
+
+    __bobthefish_start_segment $flag_colors
+    echo -ns (__bobthefish_fossil_branch) $flags ' '
+    set_color normal
+
+    set -l project_pwd (__bobthefish_project_pwd $fossil_root_dir $real_pwd)
+    if [ "$project_pwd" ]
+        if [ -w "$real_pwd" ]
+            __bobthefish_start_segment $color_path
+        else
+            __bobthefish_start_segment $color_path_nowrite
+        end
+
+        echo -ns $project_pwd ' '
+    end
+end
+
 function __bobthefish_prompt_hg -S -a hg_root_dir -a real_pwd -d 'Display the actual hg state'
     set -l dirty (command hg stat; or echo -n '*')
 
@@ -1242,6 +1306,7 @@ function fish_prompt -d 'bobthefish, a fish theme optimized for awesome'
     # VCS
     set -l git_root_dir (__bobthefish_git_project_dir $real_pwd)
     set -l hg_root_dir (__bobthefish_hg_project_dir $real_pwd)
+    set -l fossil_root_dir (__bobthefish_fossil_project_dir $real_pwd)
 
     if [ "$git_root_dir" -a "$hg_root_dir" ]
         # only show the closest parent
@@ -1255,6 +1320,8 @@ function fish_prompt -d 'bobthefish, a fish theme optimized for awesome'
         __bobthefish_prompt_git $git_root_dir $real_pwd
     else if [ "$hg_root_dir" ]
         __bobthefish_prompt_hg $hg_root_dir $real_pwd
+    else if [ "$fossil_root_dir" ]
+        __bobthefish_prompt_fossil $fossil_root_dir $real_pwd
     else
         __bobthefish_prompt_dir $real_pwd
     end

From 787236686c77e84b18c017479e88fedaeabbd974 Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Sat, 20 Apr 2024 12:48:27 -0400
Subject: [PATCH 2/6] Fix project directory discovery when outside a project
 directory

---
 functions/fish_prompt.fish | 1 +
 1 file changed, 1 insertion(+)

diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index fedd779..578916b 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -197,6 +197,7 @@ end
 
 function __bobthefish_fossil_project_dir -S -a real_pwd -d 'Print the current fossil project base directory'
     [ "$theme_display_fossil" = 'yes' ]
+    and command fossil status >/dev/null 2>/dev/null
     or return
 
     set -q theme_vcs_ignore_paths

From e59687a25db82b312d22eeb831703a5abf2b0483 Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Sat, 20 Apr 2024 19:28:26 -0400
Subject: [PATCH 3/6] Implement review feedback

---
 functions/__bobthefish_glyphs.fish |  5 +++--
 functions/fish_prompt.fish         | 33 ++++++++++++------------------
 2 files changed, 16 insertions(+), 22 deletions(-)

diff --git a/functions/__bobthefish_glyphs.fish b/functions/__bobthefish_glyphs.fish
index 036a66c..1adb236 100644
--- a/functions/__bobthefish_glyphs.fish
+++ b/functions/__bobthefish_glyphs.fish
@@ -50,7 +50,7 @@ function __bobthefish_glyphs -S -d 'Define glyphs used by bobthefish'
   set -x git_plus_minus_glyph '±'
 
   # Fossil glyph (it reuses most of the git glyphs)
-  set -x fossil_glyph '🦴'
+  set -x fossil_glyph \U1F9B4 # Unicode bone emoji
 
   # Disable Powerline fonts (unless we're using nerd fonts instead)
   if [ "$theme_powerline_fonts" = "no" -a "$theme_nerd_fonts" != "yes" ]
@@ -86,7 +86,7 @@ function __bobthefish_glyphs -S -d 'Define glyphs used by bobthefish'
     set git_stashed_glyph    \uF0C6 '' # nf-fa-paperclip
     set git_untracked_glyph  \uF128 '' # nf-fa-question
     # set git_untracked_glyph  \uF141 '' # nf-fa-ellipsis_h
-    set fossil_glyph '󰂹'
+    set fossil_glyph \UF00B9 # nf-md-bone
 
     set git_ahead_glyph      \uF47B # nf-oct-chevron_up
     set git_behind_glyph     \uF47C # nf-oct-chevron_down
@@ -99,5 +99,6 @@ function __bobthefish_glyphs -S -d 'Define glyphs used by bobthefish'
   # Avoid ambiguous glyphs
   if [ "$theme_avoid_ambiguous_glyphs" = "yes" ]
     set git_untracked_glyph '...'
+    set fossil_glyph '' # blank, for lack of a good fallback
   end
 end
diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index 578916b..61bd974 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -73,7 +73,7 @@ function __bobthefish_git_branch -S -d 'Get the current git branch (or commitish
 end
 
 function __bobthefish_fossil_branch -S -d 'Get the current fossil branch'
-    set -l branch (command fossil branch 2>/dev/null)
+    set -l branch (command fossil branch 2>/dev/null | string trim --left --chars=' *')
     echo "$branch_glyph $branch"
 end
 
@@ -1038,7 +1038,7 @@ end
 # ==============================
 
 function __bobthefish_prompt_fossil -S -a fossil_root_dir -a real_pwd -d 'Display the actual fossil state'
-    set fossil_statuses (command fossil changes --differ 2>/dev/null | cut -d' ' -f1 | sort -u)
+    set -f fossil_statuses (command fossil changes --differ 2>/dev/null | cut -d' ' -f1 | sort -u)
 
     # Fossil doesn't really stage changes; untracked files are ignored, tracked files are committed by default
     # It also syncs by default when you commit, and monitors for conflicts (which will be reported here)
@@ -1054,7 +1054,7 @@ function __bobthefish_prompt_fossil -S -a fossil_root_dir -a real_pwd -d 'Displa
         end
     end
 
-    set flags "$dirty$new$conflict"
+    set -f flags "$dirty$new$conflict"
 
     [ "$flags" ]
     and set flags " $flags"
@@ -1069,7 +1069,6 @@ function __bobthefish_prompt_fossil -S -a fossil_root_dir -a real_pwd -d 'Displa
     __bobthefish_start_segment $flag_colors
     echo -ns $fossil_glyph ' '
 
-    __bobthefish_start_segment $flag_colors
     echo -ns (__bobthefish_fossil_branch) $flags ' '
     set_color normal
 
@@ -1309,22 +1308,16 @@ function fish_prompt -d 'bobthefish, a fish theme optimized for awesome'
     set -l hg_root_dir (__bobthefish_hg_project_dir $real_pwd)
     set -l fossil_root_dir (__bobthefish_fossil_project_dir $real_pwd)
 
-    if [ "$git_root_dir" -a "$hg_root_dir" ]
-        # only show the closest parent
-        switch $git_root_dir
-            case $hg_root_dir\*
-                __bobthefish_prompt_git $git_root_dir $real_pwd
-            case \*
-                __bobthefish_prompt_hg $hg_root_dir $real_pwd
-        end
-    else if [ "$git_root_dir" ]
-        __bobthefish_prompt_git $git_root_dir $real_pwd
-    else if [ "$hg_root_dir" ]
-        __bobthefish_prompt_hg $hg_root_dir $real_pwd
-    else if [ "$fossil_root_dir" ]
-        __bobthefish_prompt_fossil $fossil_root_dir $real_pwd
-    else
-        __bobthefish_prompt_dir $real_pwd
+    # only show the closest parent
+    switch (path sort -r "$git_root_dir" "$hg_root_dir" "$fossil_root_dir")[1]
+        case ''
+            __bobthefish_prompt_dir $real_pwd
+        case "$git_root_dir"
+            __bobthefish_prompt_git $git_root_dir $real_pwd
+        case "$hg_root_dir"
+            __bobthefish_prompt_hg $hg_root_dir $real_pwd
+        case "$fossil_root_dir"
+            __bobthefish_prompt_fossil $fossil_root_dir $real_pwd
     end
 
     __bobthefish_finish_segments

From 3ae6695e201554af5a9d08f928c8317b8a0c0b1d Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Sat, 20 Apr 2024 19:55:06 -0400
Subject: [PATCH 4/6] Make a couple other variables function-scoped

---
 functions/fish_prompt.fish | 6 +++---
 1 file changed, 3 insertions(+), 3 deletions(-)

diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index 61bd974..8248df7 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -1046,11 +1046,11 @@ function __bobthefish_prompt_fossil -S -a fossil_root_dir -a real_pwd -d 'Displa
         switch $line
             case ADDED UPDATED EDITED DELETED RENAMED
                 # These can really just all be dirty, then
-                set dirty $git_dirty_glyph
+                set -f dirty $git_dirty_glyph
             case EXTRA
-                set new $git_untracked_glyph
+                set -f new $git_untracked_glyph
             case CONFLICT
-                set conflict '!'
+                set -f conflict '!'
         end
     end
 

From 88055400c309099a6bbcd1570baf6f17bebbdb1d Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Sat, 20 Apr 2024 20:59:55 -0400
Subject: [PATCH 5/6] Use `fossil status json` instead of `fossil info` for
 more consistent performance

---
 functions/fish_prompt.fish | 5 +++--
 1 file changed, 3 insertions(+), 2 deletions(-)

diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index 8248df7..fab1b59 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -197,14 +197,15 @@ end
 
 function __bobthefish_fossil_project_dir -S -a real_pwd -d 'Print the current fossil project base directory'
     [ "$theme_display_fossil" = 'yes' ]
-    and command fossil status >/dev/null 2>/dev/null
+    and command fossil json status >/dev/null 2>/dev/null
     or return
 
     set -q theme_vcs_ignore_paths
     and [ (__bobthefish_ignore_vcs_dir $real_pwd) ]
     and return
 
-    command fossil info 2>/dev/null | sed '3q;d' | string split ' ' -f2 -n | string trim --right --chars=/
+    set -f dir (command fossil json status 2>/dev/null | grep localRoot | string split ':' -f2 | string trim --chars='"/,')
+    echo "/$dir"
 end
 
 function __bobthefish_hg_project_dir -S -a real_pwd -d 'Print the current hg project base directory'

From 38b93488e56b7df3e1bb987eaed191f7c48ed64e Mon Sep 17 00:00:00 2001
From: demize <demize@unstable.systems>
Date: Sat, 20 Apr 2024 23:01:06 -0400
Subject: [PATCH 6/6] Avoid a redundant call to `fossil`

---
 functions/fish_prompt.fish | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/functions/fish_prompt.fish b/functions/fish_prompt.fish
index fab1b59..03017d0 100644
--- a/functions/fish_prompt.fish
+++ b/functions/fish_prompt.fish
@@ -197,14 +197,13 @@ end
 
 function __bobthefish_fossil_project_dir -S -a real_pwd -d 'Print the current fossil project base directory'
     [ "$theme_display_fossil" = 'yes' ]
-    and command fossil json status >/dev/null 2>/dev/null
+    and set -f dir (command fossil json status 2>/dev/null | grep localRoot | string split ':' -f2 | string trim --chars='"/,')
     or return
 
     set -q theme_vcs_ignore_paths
     and [ (__bobthefish_ignore_vcs_dir $real_pwd) ]
     and return
 
-    set -f dir (command fossil json status 2>/dev/null | grep localRoot | string split ':' -f2 | string trim --chars='"/,')
     echo "/$dir"
 end